blob: 72e8ca85b8936c3503cfe11ec23bfc767cabbb1c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
|
# Stable backports since then collide with the patch:
# - 7.2.9 "HID: multitouch: Add report ID mismatch quirk for ASUS ROG Z13
# Folio" took MT_QUIRK BIT(26) and class IDs 0x0115-0x0117, so
# MT_QUIRK_HAS_TYPE_COVER_BACKLIGHT becomes BIT(27) (with the new quirk
# as context) and MT_CLS_WIN_8_MS_SURFACE_TYPE_COVER becomes 0x0118 (with
# the three new classes as context, dropping the now-stale RAZER/SMART
# context lines).
# - 7.2.10 "HID: multitouch: stop the release timer from being rearmed on
# remove" renamed timer_delete_sync -> timer_shutdown_sync in mt_remove.
# hunk 3: stale count 12/15 -> 14/17, BIT(26) collision -> BIT(27)
s/^@@ -78,12 +78,15 @@/@@ -78,14 +78,17 @@/
s/^ #define MT_QUIRK_KEEP_LATENCY_ON_CLOSE\tBIT(25)$/&\n #define MT_QUIRK_IGNORE_FEATURE_ID_MISMATCH\tBIT(26)/
s/^+#define MT_QUIRK_HAS_TYPE_COVER_BACKLIGHT\tBIT(26)$/+#define MT_QUIRK_HAS_TYPE_COVER_BACKLIGHT\tBIT(27)/
# hunk 5: class id 0x0115 taken -> 0x0118, context updated to 7.2.15
s/^@@ -212,6 +221,7 @@/@@ -212,7 +221,8 @@/
/^ #define MT_CLS_RAZER_BLADE_STEALTH\t\t0x0112$/d
/^ #define MT_CLS_SMART_TECH\t\t\t0x0113$/d
s/^ #define MT_CLS_APPLE_TOUCHBAR\t\t\t0x0114$/&\n #define MT_CLS_YOGABOOK9I\t\t\t0x0115\n #define MT_CLS_EGALAX_P80H84\t\t\t0x0116\n #define MT_CLS_ASUS_ROG_Z13_FOLIO\t\t0x0117/
s/^+#define MT_CLS_WIN_8_MS_SURFACE_TYPE_COVER\t0x0115$/+#define MT_CLS_WIN_8_MS_SURFACE_TYPE_COVER\t0x0118/
# hunk 11: 7.2.10 rename in mt_remove
s/timer_delete_sync(&td->release_timer)/timer_shutdown_sync(\&td->release_timer)/
|
